hog = 0
/
/	add two e files
/
	setd
	setl
/
	sys	open; itap; 0
	mov	r0,tapi
	sys	read; blk0; 512.
/
	sys	open; jtap; 0
	mov	r0,tapj
	sys	read; blk1; 512.
/
	sys	creat; ktap; 17
	mov	r0,tapk
	sys	write; blk0; 512.
1:
	jsr	pc,rtapei
	dec	tblks
	blt	done
	mov	$tapea,r4
	jsr	pc,rtapej
	mov	$tapeb,r5
	mov	$tapec,r3
2:
	cmp	r5,$tapeb+1024.
	bhis	2f
	movif	(r4)+,fr0
	mulf	$eight,fr0		/*
	movif	(r5)+,fr1
	mulf	$two,fr1		/*
	subf	fr1,fr0			/*
	movfi	fr0,(r3)+
	br	2b
2:
	jsr	pc,wtapek
	br	1b
done:
	sys	exit
/
/
two	= 40400
eight	= 41000
/
/
/
rtapei:
	mov	tapi,r0
	sys	read; tapea; 1024.
	bec 9f; jmp 2f; 9:
	inc	iaddr
	cmp	iaddr,$50.
	blo	1f
	mov	tapi,r0
	sys	close
	clr	iaddr
	incb	itap+4
	sys	open; itap; 0
	bec 9f; jmp 2f; 9:
	mov	r0,tapi
1:
	sys	hog
	rts	pc
/
/
rtapej:
	mov	tapj,r0
	sys	read; tapeb; 1024.
	bec 9f; jmp 2f; 9:
	inc	jaddr
	cmp	jaddr,$50.
	blo	1f
	mov	tapj,r0
	sys	close
	clr	jaddr
	incb	jtap+4
	sys	open; jtap; 0
	bec 9f; jmp 2f; 9:
	mov	r0,tapj
1:
	sys	hog
	rts	pc
/
wtapek:
	mov	tapk,r0
	sys	write; tapec; 1024.
	bes	2f
	inc	kaddr
	cmp	kaddr,$50.
	blo	1f
	mov	tapk,r0
	sys	close
	clr	kaddr
	incb	ktap+4
	sys	creat; ktap; 17
	bes	2f
	mov	r0,tapk
1:
	sys	hog
	rts	pc
2:
	mov	$1,r0
	sys	write; 1f; 2f-1f
	mov	$1,r0
	sys	seek;0;2
	4
1:
	<IO\n>
2:
/
itap:	<xfil0\0>
jtap:	<yfil0\0>
ktap:	<zfil0\0>
	.even
/
tapi:	.=.+2
tapj:	.=.+2
tapk:	.=.+2
iaddr:	.=.+2
jaddr:	.=.+2
kaddr:	.=.+2
blk0:
	busflg:	0
	term:	0;0
	nblks:	0
	tblks:	0
tapea:	.=.+1024.
blk1:
	.=.+12
tapeb:	.=.+1024.
blk2:
	.=.+12
tapec:	.=.+1024.
/
